MS Word 테이블을 Excel 시트로 내보내기 위한 매크로

MS Word 테이블을 Excel 시트로 내보내기 위한 매크로

표가 많은 워드 문서가 있습니다.이러한 테이블을 다른 Excel 시트로 내보내기 위한 매크로 작성 방법을 아는 사람이 있습니까?

답변: http://www.mrexcel.com/forum/showthread.php?t=36875

다음은 Word에서 엑셀의 활성 워크시트로 표를 읽어내는 코드입니다.Word에 두 개 이상의 표가 있는 경우, Word 문서와 표 번호를 입력하라는 메시지가 나타납니다.

Sub ImportWordTable()
Dim wdDoc As Object
Dim wdFileName As Variant
Dim TableNo As Integer 'table number in Word
Dim iRow As Long 'row index in Excel
Dim iCol As Integer 'column index in Excel

wdFileName = Application.GetOpenFilename("Word files (*.doc),*.doc", , _
"Browse for file containing table to be imported")

If wdFileName = False Then Exit Sub '(user cancelled import file browser)

Set wdDoc = GetObject(wdFileName) 'open Word file

With wdDoc
    TableNo = wdDoc.tables.Count
    If TableNo = 0 Then
        MsgBox "This document contains no tables", _
        vbExclamation, "Import Word Table"
    ElseIf TableNo > 1 Then
        TableNo = InputBox("This Word document contains " & TableNo & " tables." & vbCrLf & _
        "Enter table number of table to import", "Import Word Table", "1")
    End If
    With .tables(TableNo)
        'copy cell contents from Word table cells to Excel cells
        For iRow = 1 To .Rows.Count
            For iCol = 1 To .Columns.Count
                Cells(iRow, iCol) = WorksheetFunction.Clean(.cell(iRow, iCol).Range.Text)
            Next iCol
        Next iRow
    End With
End With

Set wdDoc = Nothing

End Sub

이 매크로는 Word가 아닌 Excel에 삽입하여 워크시트나 워크북 이벤트 코드 모듈이 아닌 표준 매크로 모듈에 삽입해야 합니다.이를 수행하려면 VBA(키보드 Alt-TMV)로 이동하여 매크로 모듈(Alt-IM)을 삽입하고 코드를 코드페인에 붙여넣습니다.다른 (Alt-TMM)과 마찬가지로 Excel 인터페이스에서 매크로를 실행합니다.

100 이상의 페이지 테이블이 실제로 각 페이지의 개별 테이블인 경우와 같이 문서에 많은 테이블이 있는 경우, 이 코드를 쉽게 수정하여 모든 테이블을 읽을 수 있습니다.하지만 지금으로서는 모두 하나의 연속 테이블로 수정이 필요없기를 바랍니다.

---

계속 탁월하게.

데이먼

VBAexpert Excel 컨설팅 (다른 생애 : http://damonostrander.com )

모든 테이블을 루프하여 이 테이블을 변경했습니다(선택한 테이블부터 시작).

Option Explicit

Sub ImportWordTable()

Dim wdDoc As Object
Dim wdFileName As Variant
Dim tableNo As Integer 'table number in Word
Dim iRow As Long 'row index in Excel
Dim iCol As Integer 'column index in Excel
Dim resultRow As Long
Dim tableStart As Integer
Dim tableTot As Integer

On Error Resume Next

ActiveSheet.Range("A:AZ").ClearContents

wdFileName = Application.GetOpenFilename("Word files (*.doc),*.doc", , _
"Browse for file containing table to be imported")

If wdFileName = False Then Exit Sub '(user cancelled import file browser)

Set wdDoc = GetObject(wdFileName) 'open Word file

With wdDoc
    tableNo = wdDoc.tables.Count
    tableTot = wdDoc.tables.Count
    If tableNo = 0 Then
        MsgBox "This document contains no tables", _
        vbExclamation, "Import Word Table"
    ElseIf tableNo > 1 Then
        tableNo = InputBox("This Word document contains " & tableNo & " tables." & vbCrLf & _
        "Enter the table to start from", "Import Word Table", "1")
    End If

    resultRow = 4

    For tableStart = 1 To tableTot
        With .tables(tableStart)
            'copy cell contents from Word table cells to Excel cells
            For iRow = 1 To .Rows.Count
                For iCol = 1 To .Columns.Count
                    Cells(resultRow, iCol) = WorksheetFunction.Clean(.cell(iRow, iCol).Range.Text)
                Next iCol
                resultRow = resultRow + 1
            Next iRow
        End With
        resultRow = resultRow + 1
    Next tableStart
End With

End Sub

다음 트릭: Word에서 테이블 내의 테이블을 추출하는 방법을 알아냅니다.내가 정말 그러고 싶어?

TC

데이먼과 @Tim 정말 감사합니다.

docx 파일을 열도록 수정하고 사용자가 이스케이프를 확인한 후 워크시트 클리어 라인을 이동했습니다.

최종 코드는 다음과 같습니다.

Option Explicit

Sub ImportWordTable()

Dim wdDoc As Object
Dim wdFileName As Variant
Dim tableNo As Integer      'table number in Word
Dim iRow As Long            'row index in Excel
Dim iCol As Integer         'column index in Excel
Dim resultRow As Long
Dim tableStart As Integer
Dim tableTot As Integer

On Error Resume Next

wdFileName = Application.GetOpenFilename("Word files (*.docx),*.docx", , _
"Browse for file containing table to be imported")

If wdFileName = False Then Exit Sub '(user cancelled import file browser)

ActiveSheet.Range("A:AZ").ClearContents

Set wdDoc = GetObject(wdFileName) 'open Word file

With wdDoc
    tableNo = wdDoc.tables.Count
    tableTot = wdDoc.tables.Count
    If tableNo = 0 Then
        MsgBox "This document contains no tables", _
        vbExclamation, "Import Word Table"
    ElseIf tableNo > 1 Then
        tableNo = InputBox("This Word document contains " & tableNo & " tables." & vbCrLf & _
        "Enter the table to start from", "Import Word Table", "1")
    End If

    resultRow = 4

    For tableStart = tableNo To tableTot
        With .tables(tableStart)
            'copy cell contents from Word table cells to Excel cells
            For iRow = 1 To .Rows.Count
                For iCol = 1 To .Columns.Count
                    Cells(resultRow, iCol) = WorksheetFunction.Clean(.cell(iRow, iCol).Range.Text)
                Next iCol
                resultRow = resultRow + 1
            Next iRow
        End With
        resultRow = resultRow + 1
    Next tableStart
End With

End Sub

이 코드 섹션은 각 테이블을 루프하여 Excel로 복사하는 섹션입니다.테이블 번호를 카운터로 사용하여 참조하는 워크시트를 동적으로 업데이트하는 워크시트 개체를 생성할 수 있습니다.

With .tables(TableNo)
'copy cell contents from Word table cells to Excel cells
For iRow = 1 To .Rows.Count
For iCol = 1 To .Columns.Count
Cells(iRow, iCol) = WorksheetFunction.Clean(.cell(iRow, iCol).Range.Text)
Next iCol
Next iRow
End With
End With

언급URL : https://stackoverflow.com/questions/4465212/macro-to-export-ms-word-tables-to-excel-sheets